I hope it's ok if I use this post to discuss the Destruction APL in Simcraft Brulsak? (as the thread is using the APL in order to try to find out which Grimoire to take next patch)
The latest simcraft build had an update to the different APLs for each spec included for the new T15H profile. I tried using that new destruction APL with the simc-510-10 version for the live server and got a dps decrease (mainly because the line to cast CB if we are low on mana was removed and as suchthe sim is now witing from time to time doing nothing until mana is back). So assuming we have enough manareg that this does not happen next tier at the start of the tier we will have ~T14H Gear and as such I will use the old APL as a starting point for optimization.
Since last week I was trying to improve the Destruction APL (thought Destruction will be the easiest to improve). As I don't have that much time because of work at the moment I was not able to finish and still have a few problems which I could not solve atm. So I decided to post in the hope that somebody will be interested to improve the APL to make a better use of our ressources and as a consequence give us a more realistic picture.
All of my sims were done using the T14H profiles in the simc-510-10 version with the following options: 10k Iterations, World Lag Low, 450sec, 20% Variation, Patchwerk Fight, Player Skill Elite.
This does not include the changes on the ptr, but these changes should have no influence on ressource management. You still want to use the ressources when they have maximum effect (so mostly during procs).
Original APL:
Code:
actions.precombat=flask,type=warm_sun
actions.precombat+=/food,type=mogu_fish_stew
actions.precombat+=/dark_intent,if=!aura.spell_power_multiplier.up
actions.precombat+=/summon_pet
actions.precombat+=/snapshot_stats
actions.precombat+=/jade_serpent_potion
actions=curse_of_the_elements,if=debuff.magic_vulnerability.down
actions+=/use_item,name=shaskin_gloves
actions+=/jade_serpent_potion,if=buff.bloodlust.react|target.health.pct<=20
actions+=/blood_fury
actions+=/dark_soul
actions+=/service_pet,if=talent.grimoire_of_service.enabled
actions+=/grimoire_of_sacrifice,if=talent.grimoire_of_sacrifice.enabled
actions+=/summon_pet,if=talent.grimoire_of_sacrifice.enabled&buff.grimoire_of_sacrifice.down
actions+=/run_action_list,name=aoe,if=active_enemies>3
actions+=/summon_doomguard
actions+=/rain_of_fire,if=!ticking&!in_flight&active_enemies>1
actions+=/havoc,target=2,if=active_enemies>1
actions+=/shadowburn,if=ember_react
actions+=/immolate,cycle_targets=1,if=ticks_remain<add_ticks%2&target.time_to_die>=5&miss_react
actions+=/chaos_bolt,if=ember_react&(buff.backdraft.stack<3|level<86)&(burning_ember>3.5|buff.dark_soul.remains>cast_time|buff.skull_banner.remains>cast_time)&(mana.pct<=75|(buff.havoc.stack>=3&buff.havoc.remains>cast_time))
actions+=/conflagrate
actions+=/rain_of_fire,if=!ticking&!in_flight&mana.pct>=50
actions+=/incinerate
actions+=/chaos_bolt,if=mana.pct<20
First thing I wanted to improve here is a better use of Shadowburn. The original code only has the following line for SB:
Code:
actions+=/shadowburn,if=ember_react
I changed that to:
Code:
actions+=/shadowburn,if=ember_react&((buff.dark_soul.up|burning_ember>3.7|target.time_to_die<10|((cooldown.dark_soul.remains*0.08+burning_ember>4|mana.pct<50)&(buff.jade_spirit.up|buff.relic_of_yulon.up|buff.synapse_springs_2.up)))|mana.pct<20)
Not SB is only used if either Dark Soul is up, Embers are about to be capped, the enemy is about to die. The second parts calculated the average amount of embers that will be generated until the next DS is ready. This is given as a result from simcraft under resources. The normal profile gives 0.08 embers per second. That means if we are going to have an overflow of embers or under 50% mana and a proc is up (excluded essence of terror as SB does not benefit from the haste proc) then use SB.
The last part is to use it if we are about to go oom. The 50% mana option is included because otherwise most SBs would be used because of low mana during times without procs.
This change results in a 30 dps increase. The DPET from SB increases but most of the SBs are used due to low mana.
Next I was trying to use the same idea for CB.
The old CB line:
Code:
actions+=/chaos_bolt,if=ember_react&(buff.backdraft.stack<3|level<86)&(burning_ember>3.5|buff.dark_soul.remains>cast_time|buff.skull_banner.remains>cast_time)&(mana.pct<=75|(buff.havoc.stack>=3&buff.havoc.remains>cast_time))
This means: Use CB only if you have less than 3 stacks of backdraft. Use CB if you are about to cap embers or Dark Soul is active or Skull Banner is active and you have less than 75% mana (to avoid mana capping). The havoc part is only for multitargets and I'm going to focus on singletarget for the moment.
I changed this to:
Code:
actions+=/chaos_bolt,if=ember_react&(buff.backdraft.stack<3|level<86)&(burning_ember>3.5|buff.dark_soul.remains>cast_time|(cooldown.dark_soul.remains*0.08+burning_ember>4&(buff.skull_banner.remains>cast_time|buff.relic_of_yulon.remains>cast_time|buff.synapse_springs_2.remains>cast_time|buff.jade_spirit.remains>cast_time)))&mana.pct<=75
This now reads as: Use CB only if you have less than 3 stacks of backdraft. Use CB if you are about to cap embers ot if Dark Soul is up. Then once again we check if we are about to cap embers until the next DS is ready and if yes use these additional CBs if either: Skull Banner or Relic of Yulon or Synapse Springs or Jade Spirit is up and we have less than 75% mana.
So logically I would assume we get a dps increase as we should not cast our CBs now if we are about to cap but when procs are up and still go into DS with 3-4 embers. But this change gives a 330 dps loss.
I didn’t have enough time to analyze this in depth yet. With this change we get a DPET decrease for CB (~3,5k) and RoF (~2,5k), but a DPET increase for incinerate (~700). I have no idea how this can happen yet. Looking at the APL list and the Sample Sequence we see that we use less CBs only for mana. That would be the following line:
Code:
chaos_bolt,if=mana.pct<20
The amount of CBs used increases by an average of 0.7 but the number of SBs decreases by 0.6
This is probably because we use an ember shortly before reaching 20%. (Could probably be avoided by using some clever conditional to pool embers shortly before execute range) But it is no explanation how the DPET of CB can drop as we should be using it now during proccs instead of just when we are about to cap or go oom.
This is where I’m stuck atm. IF somebody has an idea why the DPET increases or some other kind of improvement idea please share.