Ask it! Macro Edition

[Pelf]

Thanks for your help. There's one problem with that macro. If i have a target selected (and no mouseover target) the macro stops working. I would like a macro that dispels/purifies my target if no mouse over target exists.

It is, as the others were suggesting, that exists is not being checked where it should be. Here's a working one:

#showtooltip
/cast [@mouseover,help,nodead] Purify; [@mouseover,harm,nodead] Dispel Magic; [help,nodead] Purify; [harm,nodead][] Dispel Magic

I always forget that while help, harm, dead, party, raid all imply exists if they're true, the no___ version does not. E.g. "[@focus,dead]" is sufficient, but "[@focus,nodead,exists]" is necessary.

I put the [] at the end to keep it from not knowing what to do without a target. It does sort of seem like Purify would be a better choice there, though. If so, then:

#showtooltip
/cast [@mouseover,help,nodead] Purify; [@mouseover,harm,nodead] Dispel Magic; [help,nodead] Purify; [harm,nodead] Dispel Magic; Purify

Sorry I didn't get it right the first time .

[Myzou]

I know it should be simple, but I can't seem to get it to work.

Anyone know how to make it so if I left click a macro, it casts Arcane Missiles, but if I right click, it not only casts Arcane Missiles, but Arcane Power, Lifeblood, Alter Time and Mana Gem? (Latter 4 are not on the GCD).

For the life of me, it's just not working with right click.

Preferably so that Alter Time is used last, so buffs are maintained after it wears off. xD

[Deleted]

#showtooltip
/use [btn:2]Arcane Power
/use [btn:2]Lifeblood
/use [btn:2]Mana Gem
/use [btn:2]Alter Time
/use Arcane Missiles

[GrieverXIII]

Hey, probably simple enough but i have yet to figure it out :/. Trying to reduce the clutter in my Druid's macro so i thought i would combine both my dispel macros (One for resto, one for the other specs).

#showtooltip
/cast [@mouseover,help][@player] Nature's Cure
/cast [@mouseover,help][@player] Remove Corruption

Is it possible to make it still show the tooltip depending wich spell is active? Currently it only shows the first one listed wich doesn't allow me to se my dispel's CD when i'm playing Balance. Thanks a lot in advance.

[Newbie95816]

Hey, probably simple enough but i have yet to figure it out :/. Trying to reduce the clutter in my Druid's macro so i thought i would combine both my dispel macros (One for resto, one for the other specs).

#showtooltip
/cast [@mouseover,help][@player] Nature's Cure
/cast [@mouseover,help][@player] Remove Corruption

Is it possible to make it still show the tooltip depending wich spell is active? Currently it only shows the first one listed wich doesn't allow me to se my dispel's CD when i'm playing Balance. Thanks a lot in advance.

#show
/use [@mouseover,help,spec:1][@player,spec:1]Remove Corruption;[@mouseover,help][@player]Nature's Cure

[Myzou]

#showtooltip
/use [btn:2]Arcane Power
/use [btn:2]Lifeblood
/use [btn:2]Mana Gem
/use [btn:2]Alter Time
/use Arcane Missiles

Oh lord, it didn't even occur to me to just make a new /use for each spell. Derp. Thanks. xD

[GrieverXIII]

#show
/use [@mouseover,help,spec:1][@player,spec:1]Remove Corruption;[@mouseover,help][@player]Nature's Cure

Thanks ^^. I didn't even knew the spec variable existed for macros >.>.

[Levelfive]

Hi, I'm trying to make a macro that lets me keep my tank targeted, cast atonement spells on the tank's target but prevents me from clipping penance. What I've had is /cast [harm][target=targettarget] Smite, which also lets me use the same macros for questing, etc (casts at my target's target but also directly at an enemy target). Adding [nochanneling:Penance] anywhere does not keep it from clipping UNLESS I remove [harm], but then it will not cast at my target's target. I have looked through many pages and sites, would appreciate any help. (Be more careful is also fair advice, but I mean with the macro!)

[aggixx]

#showtooltip
/stopmacro [channeling:Penance]
/cast [harm][@targettarget, harm] Smite

Give that a shot. You could also put a nochanneling:Penance conditional inside both sets of conditionals in front of smite, but this saves a little space.

[Levelfive]

That did the trick. Thank you times 100!

[Biomega]

Is there a way to check for range in macros?

Specifically, I want a macro to cast something at my focus, but if it's out of range cast it on my mouseover instead (as well as the usual exists/nodead checks). Is this possible?

[CodeConqueror]

Pretty sure you can't do this.

This is correct. There is no modifier or script command that can check and react to range.

[Mortarius]

I am looking for help with some Mouseover macros. I am trying to get harmful spells and healing spells in the same macro as mouseovers.

So for instance, if I mouseover a friendly unit it will cast Rejuvenation, or if I target a friendly unit it will heal them with Rejuvenation. But if the target is harmful I want it to cast Moonfire.

I got this so far:
#showtooltip
/cast [@mouseover, friendly, nodead] Rejuvenation; [@target] Rejuvenation; [harm] Moonfire.

Doesn't seem to be functioning the way I would like though. =[

[aggixx]

"friendly" isn't a valid conditional, the one you want is "help". You can also merge the two rejuv parts into one like so:

#showtooltip
/cast [@mouseover, help, nodead][help, nodead] Rejuvenation; [harm, nodead] Moonfire

[Mortarius]

Thank you very much! Works beautifully. Now I might just be too picky but is there a way that I can choose a different icon so it doesn't display the red ? when I don't have a target/mouseover, but still displays the correct tooltip when I do?

[aggixx]

Something like this should work. It could be a little cleaner though.

#showtooltip [@mouseover, help, nodead][help, nodead] Rejuvenation; [harm, nodead] Moonfire; Rejuvenation
/cast [@mouseover, help, nodead][help, nodead] Rejuvenation; [harm, nodead] Moonfire

[Mortarius]

Thank you again! You are a life saver!

[Deleted]

Something like this should work. It could be a little cleaner though.

#showtooltip [@mouseover, help, nodead][help, nodead] Rejuvenation; [harm, nodead] Moonfire; Rejuvenation
/cast [@mouseover, help, nodead][help, nodead] Rejuvenation; [harm, nodead] Moonfire

This will also work:

#showtooltip
/cast [@mouseover, help, nodead][help, nodead] Rejuvenation; [harm, nodead] Moonfire
/stopmacro
/cast Rejuvenation

[Deleted]

Hi there,
I'm having some trouble with a macro for renewing mist on my monk.
I basicly copied the mouseovermacro for renew from my priest and changed renew to renewing mist, but instead of casting RM on my mouseover target it always casts RM on my current target or myself (if I don't have a target or my target is hostile) and I absolutely don't know why.

/cast [target=mouseover,exists,help,nodead] Renewing Mist; [help,nodead] [target=player] Renewing Mist

I also tried removing the

[help,nodead] [target=player] Renewing Mist

part, but it does not change anything and again I'm at a loss as to why.

[Blasting]

Hi Rincy,

just try with:

/cast [@mouseover,help][@target,help][@targettarget,help][] Renewing Mist

should cast on mouseover if you have it and it's not hostile,
otherwise on your target if not hostile,
otherwise on your target target, again if not hostile,
otherwise just on you